# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils wxwidgets

DESCRIPTION="Cave Surveying Software (requires opengl)"
HOMEPAGE="http://www.survex.com/"
SRC_URI="http://www.survex.com/software/${PV}/${P}.tar.gz"
LICENSE="GPL-2"

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~s390 ~sparc x86"
SLOT="0"

IUSE="svxedit profile vim"
DEPEND=">=x11-libs/wxGTK-2.6
	~app-text/docbook-sgml-dtd-4.1
	app-text/sgmltools-lite
	app-text/docbook-sgml-utils"
RDEPEND="${DEPEND}
	svxedit? ( dev-tcltk/bwidget )"

pkg_setup() {
	if ! built_with_use "=x11-libs/wxGTK-2.6*" opengl; then
		eerror "${P} requires =x11-libs/wxGTK-2.6* emerged with USE='opengl'"
		eerror "If you don't have a 3D capable graphics card, use ${PN}-1.0*"
		die "opengl required"
	fi

	# no unicode please!
	export WX_GTK_VER="2.6"
	need-wxwidgets gtk2
}

src_compile() {
	if ! use svxedit; then
		sed -i 's:bin_SCRIPTS = svxedit:bin_SCRIPTS =:' src/Makefile.in
		sed -i 's:survex-svxedit.desktop::' lib/Makefile.in
		sed -i 's:svxedit.png::' lib/icons/Makefile.in
	fi
	if use vim; then
		sed -i 's:gnome-edit:gvim:' lib/survex.keys.in
	fi

	sed -i 's:manual.rtf ::' configure
	touch doc/manual.{ps,txt} doc/manual
	source /etc/sgml/sgml.env

	econf \
		WXCONFIG=${WX_CONFIG} \
		--enable-docdir=/usr/share/doc/${PF} \
		$(use_enable profile profiling) \
		|| die "econf failed"
	emake || die "emake failed"
	emake -C doc manual || eerror "emake manual failed"
}

src_install() {
	make install DESTDIR=${D} || die "install failed"

	if use vim; then
		make -C vim vimdir=/usr/share/vim/vimfiles install \
			DESTDIR=${D} || ewarn "install vim files failed"
	fi

	gzip ${D}/usr/share/doc/${PF}/manual.*
}